remote user login

Help and discussion about non-Linux operating systems

Moderators: ChrisThornett, LXF moderators

remote user login

Postby dwjs1974 » Thu Jan 15, 2009 11:38 am

Hi all, Hope everyone had a good newyear....

(machine 1)
Laptop running windowsXP media edition
(machine 2)
Is a custom build DELL not sure if will have XP or vista


What they want to do?
They would like to remotely access machine 2 using the laptop mainly to check emails. but without disrupting the user on machine 2.

I tested remote desktop and it will not allow 2 users on at the same time.
So my Question:

Does anyone know any software (free) that will allow 2 users to be logged on at the same time. in there own profiles??

Cheers

Dave
Great Scott this is heavy.
Opensuse11.1 1gig ram
Dave the Rave
User avatar
dwjs1974
LXF regular
 
Posts: 179
Joined: Fri Mar 23, 2007 4:30 pm
Location: Herefordshire UK

RE: remote user login

Postby pootman » Sun Jan 25, 2009 12:16 am

Correct me if I'm wrong, but the Windows license is the issue here - you're only allowed one user.
I vaguely remember such a useful feature nearly making it into XPSP1, but being yanked after the beta to stop such shennanigans.
There were/might still be copies of the relevant terminal services dll (termsrv?) floating around the web, but it's dodgier than it's worth IMHO.
This signature has been produced using traditional writing methods on behalf of The Campaign For Real Slogans.
To enjoy this signature at its best, adjust your monitor's resolution to 1024x768.
User avatar
pootman
LXF regular
 
Posts: 430
Joined: Tue Jan 09, 2007 12:25 pm
Location: Scotland, North of England

RE: remote user login

Postby ollie » Sun Jan 25, 2009 1:23 am

The Microsoft Remote Desktop Protocol (RDP) used to access a Windows system will either lock out the local user or share the session with the local user (Remote Assistance).
User avatar
ollie
Moderator
 
Posts: 2749
Joined: Mon Jul 25, 2005 11:26 am
Location: Bathurst NSW Australia

RE: remote user login

Postby MartyBartfast » Sun Jan 25, 2009 7:27 am

When I was faced with the same issue a few years ago I took myself off to a Windows forum to ask and their response was "Upgrade to XP Pro" which will allow multiple users, I didn't! You might get some mileage from installing an X display manager on the Windows box (Cygwin X for example) but I guess you'd be severely limited in what you can run on it that way.
I have been touched by his noodly appendage.
User avatar
MartyBartfast
LXF regular
 
Posts: 815
Joined: Mon Aug 22, 2005 7:25 am
Location: Hants, UK

RE: remote user login

Postby ollie » Sun Jan 25, 2009 11:21 am

There is a hack (use at own risk) that allows up to three RDP sessions on Windows XP Pro provided you could locate a particular version of the termsrv.dll. A guide written in 2005 for use at your own risk is available here.
User avatar
ollie
Moderator
 
Posts: 2749
Joined: Mon Jul 25, 2005 11:26 am
Location: Bathurst NSW Australia

Postby dwjs1974 » Sun Jan 25, 2009 11:36 pm

Many thanks all

i found a patch and a dll
Code: Select all

:START
   @echo off
   cls

:DETECTARGUMENTS
   SET SINGLESESSION=1
   SET BLANK=1
   IF /I *%1 == *MULTI SET SINGLESESSION=0
   IF /I *%2 == *MULTI SET SINGLESESSION=0
   IF /I *%1 == *BLANK SET BLANK=0
   IF /I *%2 == *BLANK SET BLANK=0

:SETSOURCEFOLDER
   REM This will get the folder the batch file was launched from since the current
   REM directory will change if launched from a network share
   SET SOURCEFOLDER=%~dp0
   ECHO Source Folder is %SOURCEFOLDER%

:TAKEOWNERSHIP
   echo Taking ownership of %SystemRoot%\System32\termsrv.dll
   takeown /a /f %SystemRoot%\System32\termsrv.dll
   echo Granting Administrators rights
   icacls %SystemRoot%\System32\termsrv.dll /Grant Administrators:F

:STOPTERMINALSERVICES
   echo Stopping Terminal Services
   net stop "Terminal Services"

:BACKUPTERMSRVDLL
   copy %SystemRoot%\System32\termsrv.dll %SystemRoot%\System32\*.*.bak

:COPYTERMSRVDLL
   echo Copying %SOURCEFOLDER%termsrv.dll to %SystemRoot%\System32\
   copy /y "%SOURCEFOLDER%termsrv.dll" %SystemRoot%\System32\

:IMPORTREGKEYS
   echo Importing Registry Keys
   regedit /s "%SOURCEFOLDER%termonpremium.reg"
   echo Enabling RDP
   REG ADD "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f

:SETSINGLESESSIONSETTING
   ECHO Setting fSingleSessionPerUser to %SINGLESESSION%
   REG ADD "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fSingleSessionPerUser /t REG_DWORD /d %SINGLESESSION% /f

:SETBLANKPASSWORDPOLICY
   ECHO Setting LimitBlankPasswordUser to %BLANK%
   REG ADD "HKLM\SYSTEM\CurrentControlSet\Control\Lsa" /v LimitBlankPasswordUse /t REG_DWORD /d %BLANK% /f
   
:CONFIGUREFIREWALL
   ECHO Configuring Remote Desktop in Windows Firewall
   netsh firewall set service remotedesktop enable

:STARTTERMINALSERVICES
   echo Starting Terminal Services
   net start "Terminal Services"

:PAUSE5SECONDS
   ECHO Pausing 5 seconds to give service time to start listening
   choice /n /c y /d y /t 5 > nul

:CHECKIFSERVICELISTENING
   echo Checking if Service is listening on port 3389
   SUBST
   netstat -a | find /i "3389"
   if ERRORLEVEL 1 goto SERVICENOTLISTENING

:SERVICEISLISTENING
   echo Service is listening
   goto CONTINUE

:SERVICENOTLISTENING
   echo Service is not listening

:CONTINUE
   echo Done
   Pause 


This allowed my machine to be logged in with one user while remote login via another user...

Thanks for the tips i found a dll

Dave
Great Scott this is heavy.
Opensuse11.1 1gig ram
Dave the Rave
User avatar
dwjs1974
LXF regular
 
Posts: 179
Joined: Fri Mar 23, 2007 4:30 pm
Location: Herefordshire UK


Return to Other OS

Who is online

Users browsing this forum: No registered users and 0 guests

cron